Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00035_PictLinkTool.ls

Text File | 2004-07-11 | 1.3 KB | 65 lines

--
-- PictLinkTool
--


property ancestor

property pictLinkSprite


on new me
  -- set constants:


  -- initialize the ancestor:
  set ancestor = new (script "AppTools")

  -- do other initializations:
  set pictLinkSprite = 0
  return me
end


on destruct me
  if objectP (ancestor) then destruct (ancestor)
  set ancestor = 0
end


-- wake up the PictLinkTool and assign a sprite number:

on initPictLink me, spr
  if not integerP (spr) or spr < 1 or spr > numSprites (me) then
    alert "initPictLink needs a valid sprite number as an argument."
    return
  end if

  set pictLinkSprite = spr
end


-- make a picture link, relative to the passed sprite number.
-- if the castLib of spr is "clickables" then link to "clickables PictLinks"

on makePictLink me, spr
  if not pictLinkSprite then return
  if not integerP (spr) then return

  set cLib = the name of castLib the castLibNum of sprite spr
  set mNum = the memberNum of sprite spr

  puppetSprite pictLinkSprite, TRUE
  set newLib = string (cLib && "PictLinks")
  set the memberNum of sprite pictLinkSprite to mNum
  set the castLibNum of sprite pictLinkSprite to the number of castLib newLib
end


-- clear a picture link by turning off the puppet:

on clearPictLink me
  if not pictLinkSprite then return
  puppetSprite pictLinkSprite, FALSE
end